insanity/flake.nix at master · nicolaschan/insanity · GitHub

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
{
  description = "A development environment for Rust projects";
  inputs = {
    nixpkgs.url = "github:NixOS/nixpkgs/nixos-unstable";
    flake-utils.url = "github:numtide/flake-utils";
    rust-overlay = {
      url = "github:oxalica/rust-overlay";
      inputs.nixpkgs.follows = "nixpkgs";
    };
  };
  outputs = {
    self,
    nixpkgs,
    flake-utils,
    rust-overlay,
  }:
    flake-utils.lib.eachDefaultSystem (
      system: let
        overlays = [(import rust-overlay)];
        pkgs = import nixpkgs {
          inherit system overlays;
        };
        rustToolchain = pkgs.rust-bin.stable.latest.default.override {
          extensions = ["rust-src"];
        };
        packageMetadata = builtins.fromTOML (builtins.readFile ./insanity-native-tui-app/Cargo.toml);
        pname = packageMetadata.package.name;
        version = packageMetadata.package.version;
        rustPackageOptions = pkgs: {
          inherit pname version;
          src = ./.;
          cargoLock = {
            lockFile = ./Cargo.lock;
            allowBuiltinFetchGit = true;
          };
          cargoBuildFlags = [
            "--bin"
            "insanity"
          ];
          nativeBuildInputs = [pkgs.pkg-config pkgs.perl pkgs.cmake];
          buildInputs =
            [
              pkgs.libopus
            ]
            ++ (
              if pkgs.stdenv.isDarwin
              then [
                # SDK automatically includes audio libs
              ]
              else [
                pkgs.alsa-lib
              ]
            );
        };
      in {
        devShells.default = pkgs.mkShell {
          buildInputs = with pkgs;
            [
              rustToolchain
              rust-analyzer
              cargo-edit
              cmake
              libopus
              automake
              autoconf
              perl
              pkg-config
              # web app
              nodejs_22
            ]
            ++ (
              if stdenv.isDarwin
              then [
                # SDK automatically includes audio libs
              ]
              else [
                alsa-lib
                gcc
              ]
            );
        };

        packages.default = pkgs.rustPlatform.buildRustPackage (rustPackageOptions pkgs);
        packages.static = pkgs.pkgsStatic.rustPlatform.buildRustPackage (rustPackageOptions pkgs.pkgsStatic);

        packages.docker = pkgs.dockerTools.buildLayeredImage {
          name = pname;
          tag = version;
          config = {
            Entrypoint = ["${self.packages.${system}.default}/bin/insanity"];
          };
        };
      }
    );
}