pidgin/build.gradle at master · JungleComputing/pidgin · GitHub

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
120
121
122
123
124
125
126
127
128
129
130
131
132
133
134
135
136
137
138
139
140
141
142
143
144
145
146
147
148
149
150
151
152
153
154
155
156
157
158
plugins {
    id 'java'
    id 'maven-publish'
    id 'com.jfrog.bintray' version '1.8.0'
    id 'jacoco'
    id 'eclipse'
    id 'com.github.hierynomus.license' version '0.14.0'
    id 'org.unbroken-dome.test-sets' version '2.1.1'
}

repositories {
    mavenLocal()
    mavenCentral()
    jcenter()
}

dependencies {
    compile 'nl.junglecomputing:timing:0.0.3'
    compile 'nl.junglecomputing.ipl:ipl:2.3.3'
    compile 'nl.junglecomputing.ipl:ibis-util:2.3.3'
    compile 'org.slf4j:slf4j-api:1.7.21'
    compile 'com.google.guava:guava:17.0'

    implementation 'nl.junglecomputing.ipl:ipl-impl-smartsockets:2.3.3'
    implementation 'nl.junglecomputing.ipl:ipl-impl-tcp:2.3.3'

    testCompile 'nl.junglecomputing.ipl:ipl-support:2.3.3'
    testCompile 'junit:junit:4.11'
    testCompile 'org.slf4j:slf4j-log4j12:1.7.2'
}

version = '0.2.3'

def pomConfig = {
    scm {
        url "https://github.com/junglecomputing/pidgin.git"
    }
}

license {
    ext.copyright_year = 2020
    ext.copyright_owner1 = 'Netherlands eScience Center'
    ext.copyright_owner2 = 'Vrije Universiteit Amsterdam'

    header rootProject.file('gradle/HEADER')
    strictCheck true
    excludes(["**/log4j.properties"])
    mapping {
        // IntelliJ IDEA gives "Dangling Javadoc comment." warning when default JAVADOC_STYLE is used,
        // so switch to comment style
        java = 'SLASHSTAR_STYLE'
    }
}

licenseFormat.description = "Applies the license found in the header file in files missing the header"

task sourcesJar(type: Jar, dependsOn: classes) {
    classifier = 'sources'
    from sourceSets.main.allSource
}

javadoc.failOnError = false
task javadocJar(type: Jar, dependsOn: javadoc) {
    classifier = 'javadoc'
    from javadoc.destinationDir
}

javadoc {
    include 'nl/JungleComputing/pidgin/*'
}

artifacts {
    archives sourcesJar
    archives javadocJar
}

publishing {
    publications {
	mavenJava(MavenPublication) {
	    from components.java
	    artifact sourcesJar {
		classifier "sources"
	    }
	    artifact javadocJar {
		classifier "javadoc"
	    }
	    groupId 'nl.junglecomputing'
	    artifactId 'pidgin'
	    version version

	    pom.withXml {
		def root = asNode()
                root.appendNode('url', 'https://github.com/JungleComputing/pidgin.git')
                root.children().last() + pomConfig
	    }
	}
    }
}

tasks.withType(Jar) {
    destinationDir = file("$rootDir/lib")
}

task copyRuntimeLibs(type: Copy) {
    into "lib"
    from configurations.runtime
}

bintray {
    user = System.getenv('BINTRAY_NAME')
    key = System.getenv('BINTRAY_APIKEY')
    publications = ['mavenJava']
    pkg {
	// TODO! Which repo? We can also put it in junglecomputing ...
	repo = 'JungleComputing'
	name = 'pidgin'
	userOrg = "$user"
	vcsUrl = 'https://github.com/JungleComputing/pidgin.git'
	licenses = ['Apache-2.0']
    }
}

testSets {
    integrationTest
}

jacocoTestReport {
    description 'Generate coverage report of unit tests'
    group 'Code coverage reporting'
    executionData test
    sourceSets sourceSets.main
    reports {
        xml.enabled = true // codecov depends on xml format report
    }
}

integrationTest.description = 'Run the integration tests'

check.dependsOn integrationTest

integrationTest.mustRunAfter test

task jacocoIntegrationTestReport(type: JacocoReport) {
    description 'Generate coverage report of integration tests'
    group 'Code coverage reporting'
    executionData integrationTest
    sourceSets sourceSets.main
    reports {
        xml.enabled = true // codecov depends on xml format report
    }
}

task jacocoMergedTestReport(type: JacocoReport) {
    description 'Generate combined coverage report of unit and integration tests'
    group 'Code coverage reporting'
    executionData( files { file('build/jacoco').listFiles() } )
    sourceSets sourceSets.main
}